CLEO Help Help to make a hitman cmd..

Derrekgamer · Aug 21, 2021

Hey i need a hitman cmd man can you help me please ....

The mod should be like this:

when i type the command /gethit the mod should type by it self the next commands:

wait 1 sec after /gethit was used then the mod type :

/my contract ( when that command was typed the mod should make a screen shoot)

wait 500 ms

/order ( the command /order should be used 3 times for more bullets)

wait 500 ms

/order

wait 500ms

/order

/undercover

/turn off

done until here.

Next, when im near on that player, the mod should verify the distance as example i need to be at 105 metters for no fail, if im at 100 metters the mod will tell me by a text on screen that im too close.. and if its posibile the mod will change the sniper weapon with the default (punch - it will take the sniper from my hand) that think should only work on sniper, not when i use knife.

next after i kill the target there will be a text in chat like : user (player name) has succesfully completed the contract on user (player name)

ex : Derrek has succesfully completed the contract on Ajom

Now the mod should detect that text in chat and do the next things :

When that text apear the mod should make a screenshoot, and type the fallowing commands : /turn on wait 500ms /undercover..

And if its posibile i need 3 commands.

/tn will do the fallowing thing - /turn off wait 500ms, /togw wait 500 ms, /togn wait 500ms, /togc.

/ch - will do the fallowing : /cancel hit wait 500ms, /undercover wait 500ms, /killcp wait 500ms, /turn on.

/kc - /killcp

/sp - /spawnchange

You can get the player id (name ) for the mod from the command /gethit, after using tha command /gethit, in chat will apear : You have a new contract on User (player name )

screen shot :

https://imgur.com/a/z0yEHam

Thats how you can get the player id for using the distance and all of that

////

the proper chatmessage formatting of those strings are :

You have a new contract on Player (/mycontract).

Player has succesfully completed the contract on Player for $1.000.000 ( any value from 70k to 1kk), distance: 244m, weapon sniper.

And there is one more thing..

when I connect to the server, the mod should to detect my id and name. That is for when appears in the chat Player has successfully completed the contract, it needs to me me, because that text "Player has succesfully completed the contract on player" its visibile for everyone, so when someone will make a contract, the mod will start by it self.. so The mod should work only when i did that contract not on someone else, you can do that like this:

1. Samp player connected

2. detect player id & name (detect my name and id)

if text player has succesfully completed the contract on player was found, the player who completed the contract should be the same player that was detected when i connected at point 2. If there is other player and my id or name was not detected the mod should not work (if im not the one who completed the contract.. Because as i said when someone will make a contract it will triger my mod to work with no reason so it need to work only when i completed the contract

@ajom

Derrekgamer · Aug 21, 2021

There should be at least a delay of 0,500ms after every command to avoid spam warning from the server

blvck0v · Aug 21, 2021

dude, what happened from this, you forgot how to write code or what?
from working with memory, RPCs, raknet hooks, you cant even do a script for delayed chat commands?

yo, @JaggerJam look at this proud owner of your script strugglin

Derrekgamer · Aug 21, 2021

blvck0v said:
dude, what happened from this, you forgot how to write code or what?
from working with memory, RPCs, raknet hooks, you cant even do a script for delayed chat commands?

yo, @JaggerJam look at this proud owner of your script strugglin

idk how to make waiting script and detect my player id or to read from string chat. i only know how to detect the other player id / name, only that. Idk how to make the weapon out from my hand or how to create a code that can screen shoot the screen. i only know how to detect player id and to make commands like /hvn - have a nice day . etc. I made some script yea but its no mine, dont own credits only pick them from diferent posts and learn how to join them, so i made from more small scripts 1 bigger script. without any knowlenge about that , i knowed how to make the phone.cs because i know the code to detect the player id name color etc and someone also helped me with it

Derrekgamer · Aug 21, 2021

blvck0v said:
dude, what happened from this, you forgot how to write code or what?
from working with memory, RPCs, raknet hooks, you cant even do a script for delayed chat commands?

yo, @JaggerJam look at this proud owner of your script strugglin

Code:

{$CLEO}
                 
0662: "cleo"
thread "gethit"
wait 2500

0B34: samp register_client_command "gethit" to_label @cmd_12



:cmd_39
wait 0
jump @cmd_39

////////////////////////////

:cmd_12
SAMP.IsCommandTyped(20@)
    0AF9: say "/gethit"
    wait 5000
    0AF9: say "/order"
    wait 5000
    0AF9: say "/undercover"
    wait 5000
    0AF9: say "/turn off"
   
SAMP.CmdRet()

also i tryed with this and not working it spams in chat )

that wait 5000 line, wont work idk why

Derrekgamer · Aug 21, 2021

blvck0v said:
dude, what happened from this, you forgot how to write code or what?
from working with memory, RPCs, raknet hooks, you cant even do a script for delayed chat commands?

yo, @JaggerJam look at this proud owner of your script strugglin

and btw im still using that mod from ajom with sms /call etc, all credits are there and i didnt post it anywhere, so why u need to be mad because i need help? When i made that phone script it tooks me 12 hours of searching forums and hour of crashes and issues,. and still not working after that, so im mad? Because i need help? i found it i edited it to woek on that server and did not succes so i ask for help u told me i steal it..

Parazitas · Aug 21, 2021

Derrekgamer said:

Code:

{$CLEO}
              
0662: "cleo"
thread "gethit"
wait 2500

0B34: samp register_client_command "gethit" to_label @cmd_12



:cmd_39
wait 0
jump @cmd_39

////////////////////////////

:cmd_12
SAMP.IsCommandTyped(20@)
    0AF9: say "/gethit"
    wait 5000
    0AF9: say "/order"
    wait 5000
    0AF9: say "/undercover"
    wait 5000
    0AF9: say "/turn off"

SAMP.CmdRet()

also i tryed with this and not working it spams in chat )

that wait 5000 line, wont work idk why

You can't make wait in cmd
Put everything in while true part.
Add variable like " 0@ = true " in cmd part to allow send that text from while loop..

Derrekgamer · Aug 21, 2021

Parazitas said:
You can't make wait in cmd
Put everything in while true part.
Add variable like " 0@ = true " in cmd part to allow send that text from while loop..

Yea that's what I'm talking about idk to make all of these xd

Parazitas · Aug 21, 2021

Derrekgamer said:
Yea that's what I'm talking about idk to make all of these xd

Code made with phone..

PHP:

{$CLEO .cs}
                 
0000:

repeat
Wait 0
until 0AFA:

0B34: samp register_client_command "gethit" to_label @cmd

While true
Wait 0

If 31@ == TRUE
Then
0AF9: say "/gethit"
    wait 5000
    0AF9: say "/order"
    wait 5000
    0AF9: say "/undercover"
    wait 5000
    0AF9: say "/turn off"
31@ = FALSE
End

End

:cmd
1@ = TRUE
SAMP.CmdRet()

Derrekgamer · Aug 21, 2021

Derrekgamer said:
Yea that's what I'm talking about idk to make all of these xd

Parazitas said:

Code made with phone..

PHP:

{$CLEO .cs}
                 
0000:

repeat
Wait 0
until 0AFA:

0B34: samp register_client_command "gethit" to_label @cmd

While true
Wait 0

If 31@ == TRUE
Then
0AF9: say "/gethit"
    wait 5000
    0AF9: say "/order"
    wait 5000
    0AF9: say "/undercover"
    wait 5000
    0AF9: say "/turn off"
31@ = FALSE
End

End

:cmd
1@ = TRUE
SAMP.CmdRet()

Thanks bro now I'm waiting for ajom to do the next things I need thank so much

Parazitas · Aug 21, 2021

Derrekgamer said:
Thanks bro now I'm waiting for ajom to do the next things I need thank so much

Okay.

@ajom he can't stop thinking about you xD
Good luck with that, I'm out. PEACE.

ajom · Aug 21, 2021

I appreciate the detailed workflow of your idea, but its not yet enough since there are some questions that needs to be clarified.

How do the User Know the ID/Name of the Target? What command to get it and what will the server tell me through chat?
Or Is the Hitman's Target you need to kill or hunt is == the user from the chat You have a new contract on Gabriel. (58)? Is Gabriel the Target or not?
How many Contracts can you have at the same time? is only one contract available for you or will it be many targets you can eliminate?
Explain in detail why you need to do this?

Derrekgamer said:
and if its posibile the mod will change the sniper weapon with the default (punch - it will take the sniper from my hand) that think should only work on sniper, not when i use knife.

ajom · Aug 21, 2021

From what I Understand so Far... I think this is what you want:

Code:

{
    Hitman Job Functions by AJOM
        Server IP = ???.???.???.???

    Requiremensts:
        SAMPFUNCS.asi
        SAMP 0.3.7 R1

    Notes:
        - Auto-Screenshot Feature requires FULL SCREEN MODE. So if you are running on windowed mode then F8(SAMP Screenshot) will not work.
        - For Educational Purposes only, if you bought this script from someone, then you got scammed!
        - Remove the DEBUG MESSAGES inside this script manually if it is working perfectly
}
{$CLEO}
0000:

repeat
    wait 0
until 0AFA:  is_samp_available

const
    BUFFERSIZE = 256 // if you receive BUFFER OVERFLOW message, then increase this value(BUT NOT TOO MUCH!)
    FAILDISTANCE = 105.0 // must be a decimal number // change this according to how much distance would trigger failure

    BOOLEANS = 31@
    ISGETTINGHITMAN = 0
    ISDOING_TN = 1
    ISCANCELLINGHHITMAN = 2
    DOSCREENSHOT = 3
    GETTARGETPLAYER = 4
    CHECKNEWCONTRACTS = 5
    SPAM_MYCONTRACT = 6

    PLAYERID_TARGET = 30@
    BUFFER = 29@
end
PLAYERID_TARGET = -1 // null player
0AC8: BUFFER = allocate_memory_size BUFFERSIZE

0B34: samp register_client_command "gh" to_label @CMD_GH
0B34: samp register_client_command "gethit" to_label @CMD_GetHit
0B34: samp register_client_command "tn" to_label @CMD_TN
0B34: samp register_client_command "ch" to_label @CMD_CancelHitman
0B34: samp register_client_command "kc" to_label @CMD_KillCP
0B34: samp register_client_command "sp" to_label @CMD_SpawnChange
0B34: samp register_client_command "hitman" to_label @ShowCommands

0BE3: raknet setup_incoming_rpc_hook @rpc_in

0AF8: samp add_message_to_chat "Hitman Functions by AJOM" color 0xFF00FFFF
0AF8: samp add_message_to_chat "Source Code: https://ugbase.eu/threads/help-to-make-a-hitman-cmd.22679/post-132748" color 0xFF00FFFF
0AF8: samp add_message_to_chat "Type '/hitman' to show all the possible commands of this script" color 0xFF00FFFF

while true
    wait 0
    if 08B7: test BOOLEANS bit DOSCREENSHOT // Raknet or CMD told me to perform screenshot
    then
        wait 0 // screenshot next frame
        0AB1: @PressScreenshot 0
        08C3: clear BOOLEANS bit DOSCREENSHOT // tell the main loop that we finished doing screenshot
    end
    if 08B7: test BOOLEANS bit ISGETTINGHITMAN
    then
        wait 1000 // newbie chat delay
            // waiting for raknet to detect the contract, every 5 seconds type /mycontract
        TIMERA = 5000 // initially expired timer to execute mycontract
        while true
            if TIMERA >= 5000
            then // retype mycontract
                0AF9: samp say_msg "/mycontract"
                0AF8: samp add_message_to_chat "DEBUG: I said '/mycontract'" color -1
                TIMERA = 0 // reset timer
            end
            wait 0
            if or
                08B7: test BOOLEANS bit DOSCREENSHOT // Raknet or CMD told me to perform screenshot
                88B7: not test BOOLEANS bit SPAM_MYCONTRACT // Raknet or CMD told me to stop spamming /mycontract
            then break
            end
        end
            //
        if 08B7: test BOOLEANS bit DOSCREENSHOT // Raknet or CMD told me to perform screenshot, also this indicates that you have a contract
        then
            wait 0 // screenshot next frame
            0AB1: @PressScreenshot 0
            08C3: clear BOOLEANS bit DOSCREENSHOT // tell the main loop that we finished doing screenshot
            for 0@ = 1 to 3 step 1
                wait 500 ms // average chat delay
                0AF9: samp say_msg "/order" // Order Bullets
                0AF8: samp add_message_to_chat "DEBUG: I said '/order'" color -1
            end
            wait 500 // average chat delay
            0AF9: samp say_msg "/undercover" // send the chat word "/undercover" to server
            0AF8: samp add_message_to_chat "DEBUG: I said '/undercover'" color -1
            wait 500 // average chat delay
            0AF9: samp say_msg "/turn off" // send the chat sentence "/turn off" to server
            0AF8: samp add_message_to_chat "DEBUG: I said '/turn off'" color -1
        end
        08C3: clear BOOLEANS bit ISGETTINGHITMAN // turn off gethitman routine
    end
    if 08B7: test BOOLEANS bit ISDOING_TN
    then
        wait 500 // average chat delay
        0AF9: samp say_msg "/togw" // send the chat word "/togw" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/togw'" color -1
        wait 500 // average chat delay
        0AF9: samp say_msg "/togn" // send the chat word "/togn" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/togn'" color -1
        wait 500 // average chat delay
        0AF9: samp say_msg "/togc" // send the chat word "/togc" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/togc'" color -1
        08C3: clear BOOLEANS bit ISDOING_TN // turn off TN routine
    end
    if 08B7: test BOOLEANS bit ISCANCELLINGHHITMAN
    then
        wait 500 // average chat delay
        0AF9: samp say_msg "/undercover" // send the chat word "/undercover" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/undercover'" color -1
        wait 500 // average chat delay
        0AF9: samp say_msg "/killcp" // send the chat word "/killcp" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/killcp'" color -1
        wait 500 // average chat delay
        0AF9: samp say_msg "/turn on" // send the chat sentence "/turn on" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/turn on'" color -1
        08C3: clear BOOLEANS bit ISCANCELLINGHHITMAN // disable Cancel Hitman routine
    end
    if 08B7: test BOOLEANS bit CHECKNEWCONTRACTS
    then
        0AF9: samp say_msg "/turn on" // send the chat sentence "/turn on" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/turn on'" color -1
        wait 500 // average chat delay
        0AF9: samp say_msg "/undercover" // send the chat word "/undercover" to server
        0AF8: samp add_message_to_chat "DEBUG: I said '/undercover'" color -1
        08C3: clear BOOLEANS bit CHECKNEWCONTRACTS // turn off check new contracts routine
    end

        // 100meter distance checker towards target player
    if 0B23:  samp is_player_connected PLAYERID_TARGET
    then
        0B20: samp 0@ = actor_handle_by_samp_player_id PLAYERID_TARGET
            // get distance between me and the target
        00A0: store_actor 0@ position_to 1@ 2@ 3@
        00A0: store_actor $PLAYER_ACTOR position_to 4@ 5@ 6@
        050A: 1@ = distance_between_XYZ 1@ 2@ 3@ and_XYZ 4@ 5@ 6@
            //
        if 1@ <= FAILDISTANCE // if im near the player, warn me!
        then
            0B36: samp 2@ = get_player_nickname PLAYERID_TARGET
            if 2@ > 0 // not null character
            then
                0AD1: show_formatted_text_highpriority "~r~WARNING!~n~Your are Near to %s(%d)~n~%f meters" time 250 2@ PLAYERID_TARGET 1@
                while 02D8: actor $PLAYER_ACTOR current_weapon == 34 // if im using a sniper
                    0B56: set_game_key 7 state 255 // press next weapon
                    wait 0
                    0B56: set_game_key 7 state 0 // release next weapon
                    wait 0
                end
            end
        end
    end
        //
end

:PressScreenshot // credits to parazitas
if 0AA2: 0@ = load_dynamic_library "samp.dll" // IF and SET
then
    0@ += 0x119CBC // 0.3.7 R1 > Do screenshot?
    0A8C: write_memory 0@ size 4 value true virtual_protect 0
end
0AB2: cleo_return 0

:CMD_GH
    08BD: set BOOLEANS bit ISGETTINGHITMAN // tell the main loop to execute the gethitman routine
    08BD: set BOOLEANS bit SPAM_MYCONTRACT // indicator that we are spamming the /mycontract
:CMD_GetHit
    08BD: set BOOLEANS bit GETTARGETPLAYER // tell raknet rpc listener to get the target player
    0AF8: samp add_message_to_chat "DEBUG: I said '/gethit'" color -1
    0AF9: samp say_msg "/gethit" // send the chat word "/gethit" to server
0B43: samp cmd_ret

:CMD_TN
    0AF9: samp say_msg "/turn off" // send the chat sentence "/turn off" to server
    0AF8: samp add_message_to_chat "DEBUG: I said '/turn off'" color -1
    08BD: set BOOLEANS bit ISDOING_TN // tell the main loop to execute the TN routine
0B43: samp cmd_ret

:CMD_CancelHitman
    0AF9: samp say_msg "/cancel hit" // send the chat sentence "/cancel hit" to server
    0AF8: samp add_message_to_chat "DEBUG: I said '/cancel hit'" color -1
    08BD: set BOOLEANS bit ISCANCELLINGHHITMAN // tell the main loop to execute the CH routine
0B43: samp cmd_ret

:CMD_KillCP
    0AF9: samp say_msg "/killcp" // send the chat word "/killcp" to server
    0AF8: samp add_message_to_chat "DEBUG: I said '/killcp'" color -1
0B43: samp cmd_ret

:CMD_SpawnChange
    0AF9: samp say_msg "/spawnchange" // send the chat word "/spawnchange" to server
    0AF8: samp add_message_to_chat "DEBUG: I said '/spawnchange'" color -1
0B43: samp cmd_ret

:ShowCommands
    0AF8: samp add_message_to_chat "Hitman Functions by AJOM" color 0xFF00FFFF
    0AF8: samp add_message_to_chat "Source Code: https://ugbase.eu/threads/help-to-make-a-hitman-cmd.22679/post-132748" color 0xFF00FFFF
    0AF8: samp add_message_to_chat "'/gh'{ff00ff} - Decription1 here" color 0xFF00FF00
    0AF8: samp add_message_to_chat "'/tn'{ff00ff} - Decription2 here" color 0xFF00FF00
    0AF8: samp add_message_to_chat "'/ch'{ff00ff} - Decription3 here" color 0xFF00FF00
    0AF8: samp add_message_to_chat "'/kc'{ff00ff} - Decription4 here" color 0xFF00FF00
    0AF8: samp add_message_to_chat "'/sp'{ff00ff} - Decription5 here" color 0xFF00FF00
0B43: samp cmd_ret

{$INCLUDE SF}
:rpc_in
    0BE5: raknet 0@ = get_hook_param PARAM_PACKETID
    if 0@ == RPC_SCRCLIENTMESSAGE
    then
        0BE5: raknet 0@ = get_hook_param PARAM_BITSTREAM
        0BE7: raknet 1@ = bit_stream_read 0@ type BS_TYPE_INT // string color
        0BE7: raknet 2@ = bit_stream_read 0@ type BS_TYPE_INT // string length
        if 2@ > BUFFERSIZE
        then
            chatmsg "warning! buffer overflow from %d exceeded to %d, increase 'BUFFERSIZE' Constant at the script" -1 BUFFERSIZE 2@
            0BE0: raknet hook_ret true
        end
        0BE8: raknet bit_stream 0@ read_array BUFFER size 2@  // copy the message with the specified length from the bitstream to buffer
        0BE9: raknet bit_stream 0@ reset_read_pointer
        0C1E: array BUFFER element 2@ el_size 1 = 0  // terminate the buffer with a null character
        if and // typing /gethit will tell you this
            08B7: test BOOLEANS bit GETTARGETPLAYER // I was instructed to get a target
            0C29: 0@ = stristr string1 BUFFER string2 "You have a new contract on"
            0C29: 1@ = stristr string1 BUFFER string2 ") (/mycontract)."
        then
            if 0C2A: 0@ = strchr 0@ char 40 // scan ASCII '('
            then
                0A8C: write_memory 1@ size 1 value 0 virtual_protect 0 // null character
                0@++ // next character after the '(' which is the player ID
                if 0AD4: 0@ = scan_string 0@ format "%d" 1@ // IF and SET
                then
                    if 0B23:  samp is_player_connected 1@
                    then
                        0085: PLAYERID_TARGET = 1@
                        0AF8: samp add_message_to_chat "DEBUG: I detected target ID: %d" color -1 PLAYERID_TARGET
                        08C3: clear BOOLEANS bit GETTARGETPLAYER // stop getting target players
                        08BD: set BOOLEANS bit DOSCREENSHOT // tell the main loop to perform screenshot
                    end
                end
            end
        else if 0C29: 0@ = stristr string1 BUFFER string2 "You have a contract on " // typing /mycontract will tell you this
        then 08BD: set BOOLEANS bit DOSCREENSHOT // tell the main loop to perform screenshot
        else if or
            0C21: stricmp string1 BUFFER string2 "You don't have a contract."
            0C21: stricmp string1 BUFFER string2 "Trebuie sa astepti inca 4 minute deoarece ce ai anulat/terminat un contract pentru a folosi /gethit"
        then 08C3: clear BOOLEANS bit SPAM_MYCONTRACT // tell the main loop to stop spamming /mycontract
        else if and
            0C2A: 1@ = strchr BUFFER char 40 // scan ASCII '('
            0C29: 0@ = stristr string1 BUFFER string2 ") has succesfully completed the contract on "
        then
            if 001D: 0@ > 1@ // character '(' comes first before character ')'
            then
                0A8C: write_memory 0@ size 1 value 0 virtual_protect 0 // null character
                1@++ // next characters which is the ID
                if 0AD4: 1@ = scan_string 1@ format "%d" 0@ // get the ID of the first player mentioned
                then
                    0B2B: samp 1@ = get_player_id_by_actor_handle $PLAYER_ACTOR
                    if 003B: 0@ == 1@ // the killer is ME
                    then
                        08BD: set BOOLEANS bit DOSCREENSHOT // tell the main loop to perform screenshot
                        08BD: set BOOLEANS bit CHECKNEWCONTRACTS // tell the main loop to do checknewcontracts routine
                        0AF8: samp add_message_to_chat "DEBUG: Doing Screenshot on the Contract, target fail distance detection disabled" color -1
                    end
                end
            end
        end
        end
        end
        end
    end
0BE0: raknet hook_ret true

Commands:

/hitman - show all possible commands.
/gh - perform the /GetHit > /My Contract > /Order x3 > /undercover > /turn off Macro
/tn - perform the /turn off > /togw > /togn > /togc Macro
/ch - perform the /cancel hit > /undercover > /killcp > /turn on Macro
/kc - Types /killcp
/sp - Types /spawnchange

Features:

Failure Distance Warning Text
Auto-Screenshot every time the server tells you about your current contract(using /mycontract or what so ever)
Auto-Screenshot every time you successfully completed a contract

This post will be updated as soon as we progress on achieving your perfect goal. So keep pinpointing what is missing here.

Derrekgamer · Aug 21, 2021

ajom said:
I appreciate the detailed workflow of your idea, but its not yet enough since there are some questions that needs to be clarified.

How do the User Know the ID/Name of the Target? What command to get it and what will the server tell me through chat?

Or Is the Hitman's Target you need to kill or hunt is == the user from the chat You have a new contract on Gabriel. (58)? Is Gabriel the Target or not?

How many Contracts can you have at the same time? is only one contract available for you or will it be many targets you can eliminate?

Explain in detail why you need to do this?

Hello. You can can get the user ID by fallow inf this steps. After I use /gethit command, the mod should type /my contract as the next command. After I use /gethit the mod will type /my contract, /turn off /undercover / order (3xtimes the command order.)

How to get the username / ID from this:

1. When the command /gethit its used, there will be a text : You have a new contract on Player (here is the player name)

Or there is a second way.

When the mod will use the second command that is /mycontract

There will be a text in chat :

You have a contract on player for $70.000 ( the money it's variable its not a fixed value.)

So there is two ways we can get the ID. After using the command /gethit from the text :

Hello. You can can get the user ID by fallow inf this steps. After I use /gethit command, the mod should type /my contract as the next command. After I use /gethit the mod will type /my contract, /turn off /undercover / order (3xtimes the command order.)

How to get the username / ID from this:

1. When the command /gethit its used, there will be a text : You have a new contract on Player (here is the player name)

Or there is a second way.

When the mod will use the second command that is /mycontract there will be a text that will say :

You have a contract on player or $70.000. (the money value it's variable not fixed.)

So there its two ways that we can get the player id

First is after we type the command /gethit there will be a text:

You have a new contract on Player (here is the player name

Or when the mod will type the second command /mycontract there will be another text that says

You have a contract on player.

I hope u understand.
------

Yes Gabriel it's the target. When you type /gethit and you get that text You have a new contract on ajom, it means u need to kill ajom using knife or sniper from 100+ metters.
-------

There is only 1 contract at the same time. Not more than one. U go and kill that target and u are done.
-----
I need it because there is a role play server. It's a faction. And there we need to make like 30 contracts per week. And some times I mean it happends somehow I forgot to type a command like /undercover or / turn off. Or I forgot to make a screen shot or I'm not focused on metters and I'm lower than 105 metters away from target.. And with any of these mistake we will get a faction warn, at 3 mistakes 3/3 fw and we are uninvited xd.. So I need that to make it self the job to help me and my friend to do our job without getting every day faction warn and waiting like 3 weeks for rank up..

ajom · Aug 21, 2021

Derrekgamer said:
and if its posibile the mod will change the sniper weapon with the default (punch - it will take the sniper from my hand) that think should only work on sniper, not when i use knife.

Derrekgamer said:
it means u need to kill ajom using knife or sniper from 100+ metters.

OK so you mean when you are near the target(example less than 105 meters), you want to automatically switch to knife weapon? and automatically switch to sniper when above 105 meters? or there is much case through it?

Also can you screenshot the message for You have a contract on player for $70.000, also post here the message came from the chatlog.txt

Derrekgamer · Aug 22, 2021

ajom said:
OK so you mean when you are near the target(example less than 105 meters), you want to automatically switch to knife weapon? and automatically switch to sniper when above 105 meters? or there is much case through it?

Also can you screenshot the message for You have a contract on player for $70.000, also post here the message came from the chatlog.txt

When im less than 105 metters yes switch to default weapon, there is no need to switch back to sniper, il do it my self, only if u are less than 105 metters switch to default weapon.

You have a contract on player, its from command /mycontract, the second way to get the id, i cant ss right now im not on pc

Derrekgamer · Aug 22, 2021

Like when we use the command /mycontract that text apears : You have a contract on player for $$$$$$$

ajom · Aug 22, 2021

Updated.

Parazitas · Aug 22, 2021

ajom said:
Updated.

To avoid might still possible bugs with send key, i leaving you this to use instead keypress .:
https://ugbase.eu/threads/some-snippets.20983/post-130915

ajom · Aug 22, 2021

Parazitas said:
To avoid might still possible bugs with send key, i leaving you this to use instead keypress .:
https://ugbase.eu/threads/some-snippets.20983/post-130915

Nice Snippet bro thanks. Added and Updated.

CLEO Help Help to make a hitman cmd..

Active member

Active member

Active member

Active member

Active member

Active member

God

Active member

God

Active member

God

Well-known member

Well-known member

Active member

Well-known member

Active member

Active member

Well-known member

God

Well-known member